如何实现FTP整站上传的批处理代码-创新互联

这篇文章主要介绍了如何实现FTP整站上传的批处理代码，具有一定借鉴价值，感兴趣的朋友可以参考下，希望大家阅读完这篇文章之后大有收获，下面让小编带着大家一起了解一下。

@echo off
rem 设置FTP服务器地址
set ftpIP=192.168.0.2
rem 设置FTP用户名
set ftpUser=MyUser
rem 设置FTP密码
set ftpPass=MyPass
rem 设置待上传的本地文件夹目录
set UpFolder=C:/test

rem 生成待上传的本地文件夹列表
type nul>%temp%/FolderList.txt
for /r "%UpFolder%" %%a in (.) do (
  set FullName=%%a
  setlocal enabledelayedexpansion
  set FolderName=!FullName:%UpFolder%=!
  set FolderName=!FolderName:~1,-2!
  echo,!FolderName!>>%temp%/FolderList.txt
  endlocal
)
>"%temp%/ftpFile.txt" echo,%ftpUser%
>>"%temp%/ftpFile.txt" echo,%ftpPass%
>>"%temp%/ftpFile.txt" echo bin
>>"%temp%/ftpFile.txt" (
  for /f "usebackq tokens=*" %%a in ("%temp%/FolderList.txt") do (
    echo cd /
    echo mkdir "%%a"
    echo cd "/%%a"
    echo mput "%UpFolder%/%%a/*.*"
  )
)
>>"%temp%/ftpFile.txt" echo ! rd /s /q "%UpFolder%"
>>"%temp%/ftpFile.txt" echo ! md "%UpFolder%"
>>"%temp%/ftpFile.txt" echo bye
ftp -v -i -s:"%temp%/ftpFile.txt" %ftpIP%

感谢你能够认真阅读完这篇文章，希望小编分享的“如何实现FTP整站上传的批处理代码”这篇文章对大家有帮助，同时也希望大家多多支持创新互联网站建设公司，，关注创新互联行业资讯频道，更多相关知识等着你来学习!